mirror of
https://github.com/FreeRTOS/FreeRTOS-Plus-TCP
synced 2025-10-24 03:32:36 +08:00
dcd6e58cec
* #556 Initial Cmake Module definition. * Fixing CI builds, rely on pcap. (#556) * Updating tested configurations and minor clean-up of missing network interfaces (#555) * Further clean-up based on testing with build environment. (#555) * Using single definition for libraries everywhere. (#555) * Fixing A_CUSTOM_NETWORK_IF compile option. * Identifying and fixing compile issues. * Adding in additional warnings for GNU to ignore for now. * Fixing formatting issues with uncrustify. * More warnings for GNU used by CI/CD pipeline. * Assuming custom for build tests and using latest freertos-kernel code. Updated readme for how to consume at project level. * Fixing up issues identified in the PR. Making the build_test EXCLUDE_FROM_ALL so only compiled if requested. * Changing to support C89 instead of C99. Renaming tcp_tools to tcp_utilities to mimic the directory. * Using C90 ISO. Fixing compiler warnings. * Fixing non C90 compliant declaration after statement * Separating out CMakeLists so each port is independent. * Updating warning list in code. * Fixed formatting with uncrustify. * Fix failing tests * Fix failing unit-test * Fix a typo. --------- Co-authored-by: Aniruddha Kanhere <60444055+AniruddhaKanhere@users.noreply.github.com>
76 lines
2.3 KiB
CMake
76 lines
2.3 KiB
CMake
# - Try to find libpcap include dirs and libraries
|
|
#
|
|
# Usage of this module as follows:
|
|
#
|
|
# find_package(PCAP)
|
|
#
|
|
# Variables used by this module, they can change the default behaviour and need
|
|
# to be set before calling find_package:
|
|
#
|
|
# PCAP_ROOT_DIR Set this variable to the root installation of
|
|
# libpcap if the module has problems finding the
|
|
# proper installation path.
|
|
#
|
|
# Variables defined by this module:
|
|
#
|
|
# PCAP_FOUND System has libpcap, include and library dirs found
|
|
# PCAP_INCLUDE_DIR The libpcap include directories.
|
|
# PCAP_LIBRARY The libpcap library (possibly includes a thread
|
|
# library e.g. required by pf_ring's libpcap)
|
|
# HAVE_PF_RING If a found version of libpcap supports PF_RING
|
|
|
|
find_path(PCAP_ROOT_DIR
|
|
NAMES include/pcap.h
|
|
)
|
|
|
|
find_path(PCAP_INCLUDE_DIR
|
|
NAMES pcap.h
|
|
HINTS ${PCAP_ROOT_DIR}/include
|
|
)
|
|
|
|
find_library(PCAP_LIBRARY
|
|
NAMES pcap
|
|
HINTS ${PCAP_ROOT_DIR}/lib
|
|
)
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(PCAP DEFAULT_MSG
|
|
PCAP_LIBRARY
|
|
PCAP_INCLUDE_DIR
|
|
)
|
|
|
|
include(CheckCSourceCompiles)
|
|
set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARY})
|
|
check_c_source_compiles("int main() { return 0; }" PCAP_LINKS_SOLO)
|
|
set(CMAKE_REQUIRED_LIBRARIES)
|
|
|
|
# check if linking against libpcap also needs to link against a thread library
|
|
if (NOT PCAP_LINKS_SOLO)
|
|
find_package(Threads)
|
|
if (THREADS_FOUND)
|
|
set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARY} ${CMAKE_THREAD_LIBS_INIT})
|
|
check_c_source_compiles("int main() { return 0; }" PCAP_NEEDS_THREADS)
|
|
set(CMAKE_REQUIRED_LIBRARIES)
|
|
endif ()
|
|
if (THREADS_FOUND AND PCAP_NEEDS_THREADS)
|
|
set(_tmp ${PCAP_LIBRARY} ${CMAKE_THREAD_LIBS_INIT})
|
|
list(REMOVE_DUPLICATES _tmp)
|
|
set(PCAP_LIBRARY ${_tmp}
|
|
CACHE STRING "Libraries needed to link against libpcap" FORCE)
|
|
else ()
|
|
message(FATAL_ERROR "Couldn't determine how to link against libpcap")
|
|
endif ()
|
|
endif ()
|
|
|
|
include(CheckFunctionExists)
|
|
set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARY})
|
|
check_function_exists(pcap_get_pfring_id HAVE_PF_RING)
|
|
check_function_exists(pcap_dump_open_append HAVE_PCAP_DUMP_OPEN_APPEND)
|
|
set(CMAKE_REQUIRED_LIBRARIES)
|
|
|
|
mark_as_advanced(
|
|
PCAP_ROOT_DIR
|
|
PCAP_INCLUDE_DIR
|
|
PCAP_LIBRARY
|
|
)
|