1
0
mirror of https://github.com/Kitware/CMake.git synced 2025-10-21 23:00:50 +08:00

ADSP: Add dedicated platform module

This commit is contained in:
Chris Wright
2022-03-24 11:35:40 +00:00
parent e9eabb0dcd
commit 87142bbd5f
12 changed files with 118 additions and 1 deletions

View File

@@ -0,0 +1,8 @@
ADSP_ROOT
---------
.. include:: ENV_VAR.txt
The ``ADSP_ROOT`` environment variable specifies a default value
for the :variable:`CMAKE_ADSP_ROOT` variable when there is no explicit
configuration given on the first run while creating a new build tree.

View File

@@ -28,6 +28,7 @@ Environment Variables that Control the Build
.. toctree::
:maxdepth: 1
/envvar/ADSP_ROOT
/envvar/CMAKE_APPLE_SILICON_PROCESSOR
/envvar/CMAKE_BUILD_PARALLEL_LEVEL
/envvar/CMAKE_BUILD_TYPE

View File

@@ -301,6 +301,28 @@ Windows Store may look like this:
set(CMAKE_SYSTEM_NAME WindowsStore)
set(CMAKE_SYSTEM_VERSION 8.1)
.. _`Cross Compiling for ADSP SHARC/Blackfin`:
Cross Compiling for ADSP SHARC/Blackfin
---------------------------------------
Cross-compiling for ADSP SHARC or Blackfin can be configured
by setting the :variable:`CMAKE_SYSTEM_NAME` variable to ``ADSP``
and the :variable:`CMAKE_SYSTEM_PROCESSOR` variable
to the "part number", excluding the ``ADSP-`` prefix,
for example, ``21594``, ``SC589``, etc.
This value is case insensitive.
CMake will automatically search for CCES or VDSP++ installs
in their default install locations
and select the most recent version found.
CCES will be selected over VDSP++ if both are installed.
Custom install paths can be set via the :variable:`CMAKE_ADSP_ROOT` variable
or the :envvar:`ADSP_ROOT` environment variable.
The compiler (``cc21k`` vs. ``ccblkfn``) is selected automatically
based on the :variable:`CMAKE_SYSTEM_PROCESSOR` value provided.
.. _`Cross Compiling for Android`:
Cross Compiling for Android

View File

@@ -346,6 +346,7 @@ Variables that Control the Build
.. toctree::
:maxdepth: 1
/variable/CMAKE_ADSP_ROOT
/variable/CMAKE_AIX_EXPORT_ALL_SYMBOLS
/variable/CMAKE_ANDROID_ANT_ADDITIONAL_OPTIONS
/variable/CMAKE_ANDROID_API

View File

@@ -5,3 +5,9 @@ adsp-platform-and-compilers
both CCES and VDSP++ installations,
with required configuration now done in the compiler module itself
rather than the Generic-ADSP platform module.
* A dedicated ``ADSP`` platform has been added
to replace the existing ``Generic-ADSP`` implementation.
This features automatic detection of the latest CCES/VDSP++ install
and compiler selection (``cc21k`` vs. ``ccblkfn``)
based off of the :variable:`CMAKE_SYSTEM_PROCESSOR` variable.

View File

@@ -0,0 +1,9 @@
CMAKE_ADSP_ROOT
---------------
When :ref:`Cross Compiling for ADSP SHARC/Blackfin`,
this variable holds the absolute path to the latest CCES or VDSP++ install.
The directory is expected to contain the ``cc21k.exe`` and ``ccblkfn.exe`` compilers.
This will be set automatically if a default install of CCES or VDSP++ can be found.
See also the :envvar:`ADSP_ROOT` environment variable.

View File

@@ -8,7 +8,7 @@ macro(__compiler_adsp lang)
set(CMAKE_${lang}_LINKER_WRAPPER_FLAG "-flags-link" " ")
set(CMAKE_${lang}_LINKER_WRAPPER_FLAG_SEP ",")
set(_CMAKE_${lang}_ADSP_FLAGS "-proc=${CMAKE_SYSTEM_PROCESSOR}")
set(_CMAKE_${lang}_ADSP_FLAGS "-proc=${CMAKE_ADSP_PROCESSOR}")
set(CMAKE_${lang}_COMPILE_OBJECT
"<CMAKE_${lang}_COMPILER> ${_CMAKE_${lang}_ADSP_FLAGS} <DEFINES> <INCLUDES> <FLAGS> -o <OBJECT> -c <SOURCE>")

View File

@@ -0,0 +1,2 @@
include(Platform/ADSP-Common)
__platform_adsp(C)

View File

@@ -0,0 +1,2 @@
include(Platform/ADSP-Common)
__platform_adsp(CXX)

View File

@@ -0,0 +1,36 @@
include_guard()
macro(__platform_adsp_init)
if(NOT CMAKE_ADSP_PLATFORM_INITIALIZED)
if(NOT CMAKE_SYSTEM_PROCESSOR)
message(FATAL_ERROR "ADSP: CMAKE_SYSTEM_PROCESSOR is required but not set")
endif()
set(CMAKE_ADSP_PROCESSOR "ADSP-${CMAKE_SYSTEM_PROCESSOR}")
string(TOUPPER "${CMAKE_ADSP_PROCESSOR}" CMAKE_ADSP_PROCESSOR)
set(CMAKE_ADSP_COMPILER_NAME cc21k.exe)
if(CMAKE_ADSP_PROCESSOR MATCHES "^ADSP-BF")
set(CMAKE_ADSP_COMPILER_NAME ccblkfn.exe)
endif()
set(CMAKE_ADSP_PLATFORM_INITIALIZED TRUE)
endif()
endmacro()
macro(__platform_adsp lang)
__platform_adsp_init()
set(CMAKE_${lang}_COMPILER "${CMAKE_ADSP_ROOT}/${CMAKE_ADSP_COMPILER_NAME}")
execute_process(
COMMAND "${CMAKE_${lang}_COMPILER}" "-proc=${CMAKE_ADSP_PROCESSOR}" "-version"
OUTPUT_QUIET ERROR_QUIET
RESULT_VARIABLE _adsp_is_valid_proc
)
if(NOT _adsp_is_valid_proc EQUAL 0)
message(FATAL_ERROR
"ADSP: unsupported processor '${CMAKE_ADSP_PROCESSOR}' for CMAKE_${lang}_COMPILER:\n"
" ${CMAKE_${lang}_COMPILER}"
)
endif()
endmacro()

View File

@@ -0,0 +1,26 @@
if(IS_DIRECTORY "$ENV{ADSP_ROOT}")
file(TO_CMAKE_PATH "$ENV{ADSP_ROOT}" CMAKE_ADSP_ROOT)
endif()
macro(_find_adsp_root path_pattern)
set(CMAKE_ADSP_ROOT "")
set(_adsp_root_version "0")
file(GLOB _adsp_root_paths "${path_pattern}")
foreach(_current_adsp_root_path IN LISTS _adsp_root_paths)
string(REGEX MATCH "([0-9\\.]+)/?$" _current_adsp_root_version "${_current_adsp_root_path}")
if(_current_adsp_root_version VERSION_GREATER _adsp_root_version)
set(CMAKE_ADSP_ROOT "${_current_adsp_root_path}")
set(_adsp_root_version "${_current_adsp_root_version}")
endif()
endforeach()
endmacro()
if(NOT CMAKE_ADSP_ROOT)
_find_adsp_root("C:/Analog Devices/CrossCore Embedded Studio *")
endif()
if(NOT CMAKE_ADSP_ROOT)
_find_adsp_root("C:/Program Files (x86)/Analog Devices/VisualDSP *")
endif()
if(NOT IS_DIRECTORY "${CMAKE_ADSP_ROOT}")
message(FATAL_ERROR "ADSP: could not find CCES/VDSP++ install directory ${CMAKE_ADSP_ROOT}")
endif()

View File

@@ -0,0 +1,4 @@
include(Platform/ADSP-Common)
__platform_adsp_init()
set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS FALSE)