mirror of
https://github.com/Kitware/CMake.git
synced 2025-06-29 15:17:44 +08:00
eef3e020c2
Migrate tutorial text from individual `directions.txt` files to the main tutorial document. Add some comments to source code to provide anchors for inclusion.
37 lines
1.2 KiB
CMake
37 lines
1.2 KiB
CMake
# first we add the executable that generates the table
|
|
add_executable(MakeTable MakeTable.cxx)
|
|
|
|
# add the command to generate the source code
|
|
add_custom_command(
|
|
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/Table.h
|
|
COMMAND MakeTable ${CMAKE_CURRENT_BINARY_DIR}/Table.h
|
|
DEPENDS MakeTable
|
|
)
|
|
|
|
# add the main library
|
|
add_library(MathFunctions
|
|
mysqrt.cxx
|
|
${CMAKE_CURRENT_BINARY_DIR}/Table.h
|
|
)
|
|
|
|
# state that anybody linking to us needs to include the current source dir
|
|
# to find MathFunctions.h, while we don't.
|
|
# state that we depend on our binary dir to find Table.h
|
|
target_include_directories(MathFunctions
|
|
INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}
|
|
PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
|
|
)
|
|
|
|
# use compile definitions to state if we have enabled USE_MYMATH
|
|
# and that anything that links to use will get this define
|
|
target_compile_definitions(MathFunctions INTERFACE "USE_MYMATH")
|
|
|
|
if(HAVE_LOG AND HAVE_EXP)
|
|
target_compile_definitions(MathFunctions
|
|
PRIVATE "HAVE_LOG" "HAVE_EXP")
|
|
endif()
|
|
|
|
# install rules
|
|
install(TARGETS MathFunctions DESTINATION lib)
|
|
install(FILES MathFunctions.h DESTINATION include)
|