mirror of
https://github.com/NixOS/nix.git
synced 2025-10-16 14:16:54 +08:00
1c9e11a11f
All of the existing tests only run on x86_64-linux and the whole `nixpkgsFor` makes it hard to reuse those for e.g. running the nixos tests with a sanitizer build of nix. This rips off the bandaid and removes the `nixpkgsFor` parameter in favor of a single instance of nixpkgs with a separate `nixComponents`.
77 lines
1.7 KiB
Nix
77 lines
1.7 KiB
Nix
{ lib, nixComponents, ... }:
|
|
|
|
let
|
|
# FIXME (roberth) reference issue
|
|
inputDerivation =
|
|
pkg:
|
|
(pkg.overrideAttrs (o: {
|
|
disallowedReferences = [ ];
|
|
})).inputDerivation;
|
|
|
|
in
|
|
{
|
|
# We rarely change the script in a way that benefits from type checking, so
|
|
# we skip it to save time.
|
|
skipTypeCheck = true;
|
|
|
|
nodes.machine =
|
|
{ config, pkgs, ... }:
|
|
{
|
|
|
|
virtualisation.writableStore = true;
|
|
system.extraDependencies = [
|
|
(inputDerivation config.nix.package)
|
|
];
|
|
|
|
nix.settings.substituters = lib.mkForce [ ];
|
|
|
|
environment.systemPackages =
|
|
let
|
|
run-test-suite = pkgs.writeShellApplication {
|
|
name = "run-test-suite";
|
|
runtimeInputs = [
|
|
pkgs.meson
|
|
pkgs.ninja
|
|
pkgs.jq
|
|
pkgs.git
|
|
|
|
# Want to avoid `/run/current-system/sw/bin/bash` because we
|
|
# want a store path. Likewise for coreutils.
|
|
pkgs.bash
|
|
pkgs.coreutils
|
|
];
|
|
text = ''
|
|
set -x
|
|
|
|
cat /proc/sys/fs/file-max
|
|
ulimit -Hn
|
|
ulimit -Sn
|
|
|
|
cd ~
|
|
|
|
cp -r ${nixComponents.nix-functional-tests.src} nix
|
|
chmod -R +w nix
|
|
|
|
chmod u+w nix/.version
|
|
echo ${nixComponents.version} > nix/.version
|
|
|
|
export isTestOnNixOS=1
|
|
|
|
export NIX_REMOTE_=daemon
|
|
export NIX_REMOTE=daemon
|
|
|
|
export NIX_STORE=${builtins.storeDir}
|
|
|
|
meson setup nix/tests/functional build
|
|
cd build
|
|
meson test -j1 --print-errorlogs
|
|
'';
|
|
};
|
|
in
|
|
[
|
|
run-test-suite
|
|
pkgs.git
|
|
];
|
|
};
|
|
}
|