mirror of
https://github.com/llvm-mirror/libcxx.git
synced 2025-10-23 10:07:41 +08:00
7c3b27d2c9
Summary: r342805 added support for the check-cxx-abilist target on FreeBSD, but broke the target on macOS in doing so. The problem is that the GENERIC_TARGET_TRIPLE gets overwritten after replacing the FreeBSD regular expression, which nullifies the replacement done with the darwin regular expression. Reviewers: dim, EricWF Subscribers: emaste, mgorny, krytarowski, christof, dexonsmith, cfe-commits, libcxx-commits Differential Revision: https://reviews.llvm.org/D52394 git-svn-id: https://llvm.org/svn/llvm-project/libcxx/trunk@342813 91177308-0d34-0410-b5e6-96231b3b80d8
34 lines
1.4 KiB
CMake
34 lines
1.4 KiB
CMake
|
|
if (DEFINED TARGET_TRIPLE)
|
|
if (TARGET_TRIPLE MATCHES "darwin")
|
|
# Ignore the major, minor, and patchlevel versions of darwin targets.
|
|
string(REGEX REPLACE "darwin[0-9]+\\.[0-9]+\\.[0-9]+" "darwin"
|
|
GENERIC_TARGET_TRIPLE "${TARGET_TRIPLE}")
|
|
elseif(TARGET_TRIPLE MATCHES "freebsd")
|
|
# Ignore the major and minor versions of freebsd targets.
|
|
string(REGEX REPLACE "freebsd[0-9]+\\.[0-9]+" "freebsd"
|
|
GENERIC_TARGET_TRIPLE "${TARGET_TRIPLE}")
|
|
else()
|
|
set(GENERIC_TARGET_TRIPLE "${TARGET_TRIPLE}")
|
|
endif()
|
|
endif()
|
|
|
|
# Detect if we are building in the same configuration used to generate
|
|
# the abilist files.
|
|
set(ABILIST_FILE "${CMAKE_CURRENT_LIST_DIR}/${GENERIC_TARGET_TRIPLE}.v${LIBCXX_ABI_VERSION}.abilist")
|
|
set(SYMDIFF_EXE "${LIBCXX_SOURCE_DIR}/utils/sym_diff.py")
|
|
if (EXISTS "${ABILIST_FILE}"
|
|
AND TARGET cxx_shared
|
|
AND ("${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "libcxxabi" OR
|
|
(APPLE AND "${LIBCXX_CXX_ABI_LIBNAME}" STREQUAL "default"))
|
|
AND NOT LIBCXX_ABI_UNSTABLE)
|
|
add_custom_target(check-cxx-abilist
|
|
${SYMDIFF_EXE} --only-stdlib-symbols --strict ${ABILIST_FILE}
|
|
$<TARGET_SONAME_FILE:cxx_shared>
|
|
DEPENDS cxx_shared
|
|
COMMENT "Testing ABI compatibility...")
|
|
else()
|
|
message(STATUS "there is no pre-generated ABI list for the requested libc++ configuration. "
|
|
"check-cxx-abilist target is not supported")
|
|
endif()
|